Home / HomePage / Scripts / ping arp subnet

ping arp subnet

Table of Contents [ Hide]

VBscript version

This script performs the painful math to figure out what IP's are included in a subnet range. Optionally, it can ping them all, and perform ARP resolution. Note that ARP resolution only works for those systems that are in the same broadcast domain as the computer where this script runs. ARP doesn't traverse routers.

(grr, I hate having to recreate this page after losing it to the wiki gods, who frown on page renames!)

First, some sample output:

H:\>cscript subnetq.vbs /?
Usage example:

cscript subnetq.vbs /IP:1.2.3.4 /mask:255.255.255.0 /ping

Where:
/IP: specifies a valid IP address and MUST be supplied.
/mask: specifies a valid subnet mask and MUST be supplied
/ping is optional. If supplied, every host in the subnet will be pinged, and result shown.

Most invalid subnet masks will be flagged as such and the script will end.
There is no checking for valid IP address yet!

H:\>cscript subnetq.vbs /ip:10.0.0.2 /mask:255.255.255.240

IP Address: 10.0.0.2
Subnet Mask: 255.255.255.240

Network ID: 10.0.0.0
Broadcast IP = 10.0.0.15
NumberofIPs (including NetworkIP and Broadcast IP): 16
First Host IP = 10.0.0.1
Last Host IP = 10.0.0.14

H:\>cscript subnetq.vbs /ip:10.0.0.2 /mask:255.255.255.240 /ping

IP Address: 10.0.0.2
Subnet Mask: 255.255.255.240

Network ID: 10.0.0.0
Broadcast IP = 10.0.0.15
NumberofIPs (including NetworkIP and Broadcast IP): 16
First Host IP = 10.0.0.1
Last Host IP = 10.0.0.14

Pinging all hosts in subnet.
3 pings per host will be sent; timeout value = 1 second.
If any ping is replied to, the host is considered ALIVE.

10.0.0.1 ping failed, no ARP.
10.0.0.2 is ALIVE, MAC(s) 00-0c-29-73-48-7f
10.0.0.3 ping failed, MAC(s) 00-0c-29-a1-7e-c5 <--this firewalled system doesn't reply to ping. But no firewall fools ARP!
10.0.0.4 ping failed, no ARP.
10.0.0.5^C
H:\>

To run this script on your own Windows system, just copy/paste to Notepad. The line numbers will not be part of the copy and they are not needed. Save it as "subnetq.vbs" (or some other name you choose), then open a cmd window, change to the directory you saved in, and run cscript subnetq.vbs - it'll tell you the parameters it needs.

Here is the full script:

Option Explicit

dim colArgs, strIPAddress, strSubnetmask

set colArgs = WScript.Arguments.Named

strIPAddress = colArgs.Item("IP")

strSubnetmask = colArgs.Item("mask")

if strIPAddress = "" Then HelpExit

if strSubnetmask = "" Then HelpExit

Wscript.echo

Wscript.Echo "IP Address: " & strIPaddress

wscript.echo "Subnet Mask: " & strSubnetmask

Wscript.echo

Dim arrNetIDNumIPs

arrNetIDNumIPs = CalcNetIDandNumIPs(strIPaddress, strSubnetmask)

Dim strNetworkID

strNetworkID = arrNetIDNumIPs(0)

Wscript.Echo "Network ID: " & strNetworkID

Dim intNumberofIPs

intNumberofIPs = arrNetIDNumIPs(1)

Dim strBroadcastIP

strBroadcastIP = CalcBroadcastIP(strNetworkID,intNumberofIPs)

wscript.echo "Broadcast IP = " & strBroadcastIP

Wscript.echo "NumberofIPs (including NetworkIP and Broadcast IP): " & intNumberofIPs

Wscript.Echo "First Host IP = " & IncrementIP(strNetworkID)

Wscript.Echo "Last Host IP = " & CalcLastHostIP(strBroadcastIP)

If colArgs.Exists("ping") Then Call PingSubnet(strNetworkID, intNumberofIPs)

sub PingSubnet(strNetworkID, intNumberofIPs)

Wscript.Echo

Wscript.Echo "Pinging all hosts in subnet."

Wscript.Echo "3 pings per host will be sent; timeout value = 1 second."

Wscript.Echo "If any ping is replied to, the host is considered ALIVE."

Wscript.Echo

Dim strPingIP

strPingIP = IncrementIP(strNetworkID)

Call PingHost(strPingIP)

getArp(strPingIP)

wscript.echo vbcr

Dim i

For i = 1 to (intNumberofIPs - 3)

strPingIP = IncrementIP(strPingIP)

Call PingHost(strPingIP)

GetArp(strPingIP)

Wscript.stdout.write vbcrlf

Next

End Sub

sub PingHost(strPingIP)

Dim WshShell, WshPing, strPingResults

Wscript.StdOut.Write strPingIP

Set WshShell = WScript.CreateObject("WScript.Shell")

Set WshPing = WshShell.Exec("ping -n 3 -w 1000 " & strPingIP) 'send 3 echo requests, waiting 1 sec each

strPingResults = LCase(WshPing.StdOut.ReadAll)

If InStr(strPingResults, "reply from") Then

WScript.StdOut.Write " is ALIVE"

'    GetArp(strPingIP)

Else

WScript.StdOut.Write " ping failed"

'    getArp(strPingIP)

End If

end Sub

Function GetArp(strPingIP)

Dim WshShell, WshArp, strArpResult

Set WshShell = WScript.CreateObject("WScript.Shell")

Set WshArp = WshShell.Exec("arp -a " & strPingIP)

strArpResult = WshArp.StdOut.ReadAll

Dim RegEx, Matches, Match

Set RegEx = New RegExp

RegEx.IgnoreCase = True

RegEx.Global = True

RegEx.Pattern = "[0-9A-F]{2}-[0-9A-F]{2}-[0-9A-F]{2}-[0-9A-F]{2}-[0-9A-F]{2}-[0-9A-F]{2}"

If Regex.Test(strArpResult) = True then

Wscript.StdOut.Write ", MAC(s)"

Set Matches = RegEx.Execute(strArpResult)

For each Match in Matches

if not Match = "00-00-00-00-00-00" Then

wscript.StdOut.Write " " & Match

Else wscript.stdout.write " -"

End If

Next

Else wscript.stdout.write ", no ARP."

End if

End Function

Function CalcLastHostIP(strBroadcastIP)

Dim arrBroadcastIP

arrBroadcastIP = Split(strBroadcastIP,".")

CalcLastHostIP = arrBroadcastIP(0) &"."& arrBroadcastIP(1) &"."&arrBroadcastIP(2) &"."& (arrBroadcastIP(3) - 1)

End Function

Function CalcBroadcastIP(strNetworkID,intNumberofIPs)

CalcBroadcastIP = strNetworkID

dim i

For i = 1 to (intNumberofIPs - 1)

CalcBroadcastIP = IncrementIP(CalcBroadcastIP)

Next

End Function

Function CalcNetIDandNumIPs(strIPaddress, strSubnetmask) 'check for proper subnet mask values; calc NetworkID; calc Number of IPs

Dim arrReturn(2)

Dim arrSubnetmask 'each octet is an element of the array

Dim arrIPaddress'each octet is an element of the array

arrSubnetmask = Split(strSubnetmask,".")

arrIPaddress = Split(strIPaddress,".")

Dim arrNetworkIP(3) 'the starting address for the subnet

Dim arrBroadcastIP(3) 'the final (ending) address for the subnet

Dim intOctet 'counter to determine which of the four octets (0 to 3) we are processing

intOctet = 0

Dim intNumIPsPerOctet 'number of IPs (or networks) allowed by the octet (a multiplier value)

Dim intNumIPs 'number of hosts the mask allows (including broadcast IP & network address IP)

intNumIPs = 1

Call SubnetmaskContainsProperValues(strSubnetmask, arrSubnetmask,0) 'test for proper values in subnet mask

Do Until intOctet = 4 'parse each octet separately, check for proper values and calculate NetworkID & Number of IPs

Select Case arrSubnetmask(intOctet)

Case "0"

intNumIPsPerOctet = 256 - arrSubnetmask(intOctet)

Call Subnetmask0FollowedBy0(strSubnetmask, arrSubnetmask, intOctet)

arrNetworkIP(intOctet) = CalcNetworkID(arrIPAddress(intOctet), intNumIPsPerOctet)

Case "255"

intNumIPsPerOctet = 256 - arrSubnetmask(intOctet)

Call Subnetmask255PrecededBy255(strSubnetmask, arrSubnetmask, intOctet)

arrNetworkIP(intOctet) = CalcNetworkID(arrIPAddress(intOctet), intNumIPsPerOctet)

Case Else

intNumIPsPerOctet = 256 - arrSubnetmask(intOctet)

Call SubnetmaskOthervalFollowedBy0s(strSubnetmask, arrSubnetmask, intOctet)

Call SubnetmaskOthervalPrecededBy255s(strSubnetmask, arrSubnetmask, intOctet)

arrNetworkIP(intOctet) = CalcNetworkID(arrIPAddress(intOctet), intNumIPsPerOctet)

End Select

intNumIPs = intNumIPs * IntNumIPsPerOctet

intOctet = IntOctet + 1

Loop

arrReturn(0) = arrNetworkIP(0) &"."& arrNetworkIP(1) &"."& arrNetworkIP(2) &"."& arrNetworkIP(3)

arrReturn(1) = intNumIPs

CalcNetIDandNumIPs = arrReturn

end Function

Function CalcNetworkID(OctetVal, IntNumIPsPerOctet) 'calculate the network ID

Dim intWhichNet

Dim intStartAddress

intWhichNet = OctetVal \ intNumIpsperOctet 'integer result only; we don't care about the remainder

CalcNetworkID = intWhichNet * IntNumIPsPerOctet

End Function

Function IncrementIP(strStartIP)

'takes IP as string, increments it by 1

Dim arrStartIP

arrStartIP = Split(strStartIP,".")

if arrStartIP(3) < 255 then

arrStartIP(3) = arrStartIP(3) + 1

else

if arrStartIP(2) < 255 then

arrStartIP(2) = arrStartIP(2) + 1

arrStartIP(3) = 0

else

if arrStartIP(1) < 255 then

arrStartIP(1) = arrStartIP(1) + 1

arrStartIP(2) = 0

arrStartIP(3) = 0

else

if arrStartIP(0) < 255 then

arrStartIP(0) = arrStartIP(0) + 1

arrStartIP(2) = 0

arrStartIP(2) = 0

arrStartIP(3) = 0

else

wscript.echo "Oops, cannot increment past 255.255.255.255 !"

wscript.quit

end if

end if

end if

end if

IncrementIP = arrStartIP(0) &"."& arrStartIP(1) &"."& arrStartIP(2) &"."& arrStartIP(3)

End Function

Sub SubnetmaskOthervalFollowedBy0s(strSubnetmask, arrSubnetmask, intOctet)

'all values following octet(iterator) that's not 255 or 0 must be 0

if intOctet = 3 Then Exit Sub 'don't perform check on last octet!

Dim iterator

iterator = intOctet + 1

For iterator = intOctet + 1 to Ubound(arrSubnetmask)

if arrSubnetmask(iterator) <> 0 Then

Wscript.Echo "Subnet Mask (" &strSubnetmask& ") octet value {128, 192, 224, 240, 248, 252, 254} is not followed by all zeros."

ExitBadSubnetMask(strSubnetMask)

end if

Next

end sub

Sub SubnetmaskOthervalPrecededBy255s(strSubnetmask, arrSubnetmask, intOctet)

'all values preceding octet(iterator) that's not 255 or 0 must be 255

if intOctet = 0 Then Exit Sub 'don't perform check on first octet!

Dim iterator

iterator = intOctet -1

For iterator = Lbound(arrSubnetmask) to intOctet - 1

if arrSubnetmask(iterator) <> 255 Then

Wscript.Echo "Subnet Mask (" &strSubnetmask& ") octet value {128, 192, 224, 240, 248, 252, 254} is not preceded by all 255s."

ExitBadSubnetMask(strSubnetMask)

end if

Next

end Sub

Sub Subnetmask0FollowedBy0(strSubnetmask, arrSubnetmask, intOctet)

'octet value 0 must be followed by 0's

if intOctet = 3 Then Exit Sub 'don't perform check on last octet!

Dim iterator

iterator = intOctet + 1

For iterator = (intOctet + 1) to Ubound(arrSubnetmask)

if arrSubnetmask(iterator) <> 0 Then

Wscript.Echo "Subnet Mask (" &strSubnetmask& ") octet value 0 is not followed by 0."

ExitBadSubnetMask(strSubnetMask)

end if

Next

end sub

Sub Subnetmask255PrecededBy255(strSubnetmask, arrSubnetmask, intOctet)

'255 must be preceeded by 255s

if intOctet = 0 Then Exit Sub 'don't perform check on first octet!

Dim iterator

For iterator = intOctet to Lbound(arrSubnetmask) step -1

if arrSubnetmask(iterator) <> 255 Then

Wscript.Echo "Subnet Mask (" &strSubnetmask& ") octet value 255 is not preceded by all 255s."

ExitBadSubnetMask(strSubnetMask)

end if

Next

end sub

sub SubnetmaskContainsProperValues(strSubnetmask, arrSubnetmask, intOctet)

'There must be 4 octets

'and each octet must be one of: 0, 128, 192, 224, 240, 248, 252, 254, 255

Dim iterator

Dim arrSubnetProperValues

If Ubound(arrSubnetmask) <> 3 Then

wscript.Echo "The subnet mask must contain 4 octets; given mask (" &strSubnetmask& ") does not."

ExitBadSubnetMask(strSubnetmask)

End If

arrSubnetProperValues = Array(0, 128, 192, 224, 240, 248, 252, 254, 255)

Dim FoundAProperValue

FoundAProperValue = False

Dim SubnetProperValuesCounter

For iterator = Lbound(arrSubnetMask) to Ubound(arrSubnetmask)

For SubnetProperValuesCounter = Lbound(arrSubnetProperValues) to Ubound(arrSubnetProperValues)

if arrSubnetmask(iterator) = Cstr(arrSubnetProperValues(SubnetProperValuesCounter)) Then FoundAProperValue=True

Next

if not FoundAproperValue = True Then

wscript.Echo "Each subnet mask octet must be one of: 0, 128, 192, 224, 240, 248, 252, 254, 255"

ExitBadSubnetMask(strSubnetmask)

End If

FoundAProperValue=False

Next

end sub

sub ExitBadSubnetMask(strSubnetMask)

Wscript.Echo "Bad subnet mask " & strSubnetmask & " - exiting."

Wscript.Quit

End Sub

sub HelpExit

Wscript.Echo "Usage example:"

Wscript.Echo

Wscript.Echo "cscript " & Wscript.ScriptName & " /IP:1.2.3.4 /mask:255.255.255.0 /ping"

wscript.Echo

Wscript.Echo "Where:"

Wscript.Echo "/IP: specifies a valid IP address and MUST be supplied."

Wscript.Echo "/mask: specifies a valid subnet mask and MUST be supplied"

Wscript.Echo "/ping is optional. If supplied, every host in the subnet will be pinged, and result shown."

Wscript.Echo

Wscript.Echo "Most invalid subnet masks will be flagged as such and the script will end."

Wscript.Echo "There is no checking for valid IP address yet!"

Wscript.Quit

end sub

I purposely did not use any binary functions/math in building this script, because I wanted to get a better mental model of how subnetting works. And I'm just never going to be one of those people who does binary math in his head. So, after much fiddling, I arrived at the following method.

First I need to calculate the number of IP's that the subnet range will hold. To get started, I break the subnet mask down into its component octets (they are called octets because they're actually the decimal representation of an 8 bit binary number). If we have a subnet mask of 255.255.255.240, it looks like this:

255 255 255 240

I handle each octet individually. To figure out how many IPs/nets each octet will hold, the formula is simple: 256 - octet. So ..

256 - 255 = 1 256 - 255 = 1 256 - 255 = 1 256 - 240 = 16

Then I multiply them all together: 1 * 1 * 1 * 16 = 16

The subnet can hold 16 IP addresses. Great. Now I need to calculate the NetworkID, which is the first IP in the subnet. This isn't an IP you can realistically use for any host. To calculate the network ID, I use the formula

( IPoctet \ numberIPsPerOctet ) * numberIPsPerOctet

Take careful note of the backslash there. It signifies integer division, which is to say, we only want a whole number as a result. So, 5/2 = 2.5, but 5\2 = 2. We always round down to the nearest whole number. So even a result of 2.9999 would become ... 2. Here's how that plays out, for an IP of 10.0.0.42:

10 0 0 42

( 10 \ 1 ) * 1 = 10 ( 0 \ 1 ) * 1 = 0 ( 0 \ 1 ) * 1 = 0 ( 42 \ 16 ) * 16 = 32

... and so the resulting Network ID is ... drumroll please ... 10.0.0.32! So now we have:

Network ID = 10.0.0.32 (this is also the starting IP)
Total number of IPs in the subnet = 16

(Note that in the script, all of the above math is done in the function CalcNetIDandNumIPs, which calls CalcNetworkID at need. CalcNetIDandNumIPs also calls 4 different subroutines whose only job is to verify that the subnet mask is itself valid. But the code for those is fairly straightforward and they are well commented, so I will let you figure them out for yourself.

The hard work is mostly done. I can simply count forward from that starting address to get to the ending address in the range. Except ... what if the range is large enough that I need to increment through two or more octets? For instance, a subnet mask of 255.255.254.0 includes 512 addresses. I needed to write the IncrementIP function to take care of the special counting. It basically works like this:

If 4th octet is < 255, then add 1 to 4th octet, else
If 3rd octet is <255, then add 1 to 3rd octet and set 4th octet to zero, else
    If 2nd octet is <255, then add 1 to 2nd octet and set 3rd and 4th octets to zero, else
       If 1st octet is <255, then add 1 to 1st octet and set 2nd, 3rd, and 4th octets to zero, else
         error! cannot increment past 255.255.255.255 ! (this should never happen anyway, because of earlier error checking)

So, to get the Broadcast IP (which is the last IP in the range), I just IncrementIP starting at the Network ID and going as many times as there are IPs in the subnet. CalcBroadcastIP handles this.

To get the first usable host IP, just add one to the 4th octet of the Network ID. To get the last usable host IP, subtract 1 from the last octet of the Broadcast IP.

All this seems simple now. But it took me 6-8 hours to figure it out and code it the first time! I'd appreciate any comments you might have, about how this could have been done better or more succinctly.

Simpler CMD version

Someone asked me for a simpler version in CMD. This one simply grabs the gateway address from ipconfig /all, assumes it is a class C address, and pings all IP's in the class C subnet of which that gateway is a member. It's not thoroughly tested but on quick run-thorough, it seems to do the job.

@echo off
setlocal
for /f "tokens=2 delims=:" %%a in ('ipconfig /all ^|findstr Gateway') do call :PINGSUBNET %%a
goto :eof
endlocal

:PINGSUBNET
set gateway=%1
for /f "tokens=1-3 delims=." %%a in ("%gateway%") do set prefix=%%a.%%b.%%c
if not "%prefix%"=="" for /l %%a in (1,1,254) do (set pingaddr=%prefix%.%%a) & call :PINGIP
goto :eof

:PINGIP
arp -d *
ping -n 1 -w 300 %pingaddr% >nul
for /f "tokens=2" %%a in ('arp -a ^| findstr %pingaddr%') do echo IP %pingaddr% .. ARP %%a
set pingaddr=