'Windows Update Script
'Uses WUA: http://msdn.microsoft.com/en-us/library/bb905331.aspx
'TODO: add a switch to allow for offline scanning (offline UPDATES would be a harder problem)
'http://msdn.microsoft.com/en-us/library/aa387290(VS.85).aspx
'http://support.microsoft.com/kb/927745
'http://support.microsoft.com/kb/926464
'TODO: consider a switch for High Impact updates (+ reboot and re-run script)
'TODO: consider an /only switch to apply only a single update. ie: /only:KB948590
Option Explicit
Dim colArgs
set colArgs = Wscript.Arguments.Named
HandleArgs
UseCscript
CheckWuaVersion
'global vars and the updateSearcher object
Dim updateSession, updateSearcher, searchResult
Dim updatesToDownload, updatesToInstall, failcount, rebootcount
Set updatesToDownload = CreateObject("Microsoft.Update.UpdateColl")
Set updatesToInstall = CreateObject("Microsoft.Update.UpdateColl")
Set updateSession = CreateObject("Microsoft.Update.Session")
Set updateSearcher = updateSession.CreateupdateSearcher()
Wscript.Echo
WScript.Echo "Searching for updates."
Wscript.Echo "Requires internet connection to Windows Update; please wait."
Wscript.Echo "(Should complete within 3 minutes at most.)"
'Type can be Software or Driver. we won't do drivers.
On Error Resume Next
Set searchResult = updateSearcher.Search("IsInstalled=0 and Type='Software'")
If Err.Number <> 0 Then Call WUAError(Err.Number)
On Error GoTo 0
'the rest of the script is written as subroutines (I like code folding under EditPad Pro!)
CheckForCompletion
ListUpdatesNeeded
CheckIfAdmin
DownloadUpdates
ApplyUpdates
CleanupExit
sub HandleArgs 'handle arguments specified in commandline
if colArgs.Count = 0 Then HelpExit
if colArgs.Exists("?") Then HelpExit
if colArgs.Exists("help") Then HelpExit
if colArgs.Exists("-help") Then HelpExit
end sub
sub UseCscript 'make sure we are running in cscript - warn and exit if not
Dim Result, sUseCscript
Set Result = CreateObject("Scripting.Dictionary")
If UCase(Right(WScript.FullName,11)) = "WSCRIPT.EXE" Then
sUseCscript = "This script is commandline only; please use cscript." & vbCr
sUseCscript = sUseCscript & "In a cmd window, change to proper folder and type:" & vbCr & vbCr
sUseCscript = sUseCscript & "cscript " & Wscript.ScriptName & vbCr & vbCr
sUseCscript = sUseCscript & "(Hint) You can make cscript your default script" &vbCr
sUseCscript = sUseCscript & "engine by typing: cscript //I //H:cscript //S"
WScript.Echo sUseCscript
WScript.Quit(-1)
End If
end sub
sub CheckWuaVersion 'Verify a usable version of Windows Update Agent is present
'W2000 SP4 has 5.8.0.2469 and that works fine (does not update itself though)
'http://msdn.microsoft.com/en-us/library/aa387099.aspx says W2000 SP3 or above
'TODO: latest WUA is 7.2.6001.784 - detect. if not installed, determine x86 or x64 OS. download as appropriate:
'http://download.windowsupdate.com/WindowsUpdate/redist/standalone/7.2.6001.784/WindowsUpdateAgent30-x86.exe
'http://download.windowsupdate.com/WindowsUpdate/redist/standalone/7.2.6001.784/WindowsUpdateAgent30-x64.exe
'(using http://blog.netnerds.net/2007/01/vbscript-download-and-save-a-binary-file/)
'install with: /wuforce /quiet /norestart (be sure script waits for completion)
Dim strWuaVersion
strWuaVersion = WuaVersion
If strWuaVersion = "0" Then
Wscript.Echo "Error: missing WUA version."
Wscript.Echo "Need to have Windows 2000 SP3 or above to use this script."
Wscript.Quit
ElseIf strWuaVersion = "7.2.6001.788" Then
Wscript.Echo "WUA version: " & strWuaVersion & " (Latest known version. Excellent!)"
ElseIf strWuaVersion => "5.8.0.2469" Then
If colArgs.Exists("updatewua") Then
Wscript.Echo "WUA version " & strWuaVersion & " found. Updating."
UpdateWUA
Else
Wscript.Echo "WUA version: " & strWuaVersion & " (OK, but updating WUA would be good!)"
Wscript.Echo "http://support.microsoft.com/kb/949104 for latest version."
Wscript.Echo "or use the /updateWUA flag to have this script update to 7.2.6001.788."
End If
Else
Wscript.Echo "WUA version is too old to use this script."
Wscript.Echo "Upgrade to Windows 2000 SP3 or higher version of OS."
Wscript.Quit
End If
End Sub
Sub UpdateWUA 'Update Windows Update Agent
Dim OSbits, oFS, TempDir, WshShell, oExec
OSbits = OScpuEdition
Set oFS = CreateObject("Scripting.FileSystemObject")
Set TempDir = oFS.getSpecialFolder(2)
Set WshShell = CreateObject("WScript.Shell")
Select Case OSbits
Case 32
Wscript.Echo "Downloading Windows Update Agent v7.2.6001.788 (x86)"
CallDownloadFile("http://download.windowsupdate.com/windowsupdate/redist/standalone/7.2.6001.788/windowsupdateagent30-x86.exe")
Wscript.stdOut.Write "Updating .. "
Set oExec = WshShell.Exec(TempDir & "\windowsupdateagent30-x86.exe /wuforce /quiet /norestart")
Do While oExec.Status = 0
WScript.Sleep 100
Loop
Wscript.stdOut.WriteLine "Done."
Case 64
Wscript.Echo "Downloading Windows Update Agent v7.2.6001.788 (x86)"
CallDownloadFile("http://download.windowsupdate.com/windowsupdate/redist/standalone/7.2.6001.788/windowsupdateagent30-x64.exe")
Wscript.stdOut.Write "Updating .. "
Set oExec = WshShell.Exec(TempDir & "\windowsupdateagent30-x64.exe /wuforce /quiet /norestart")
Do While oExec.Status = 0
WScript.Sleep 100
Loop
Wscript.stdOut.WriteLine "Done."
Case Else
Wscript.Echo "Could not detect whether OS is x86, x84, or Itanium. Quitting."
Wscript.Quit
End Select
End Sub
sub CheckForCompletion 'if no updates needed, inform user and exit
If searchResult.Updates.Count = 0 Then
WScript.Echo "This system is fully up to date!"
WScript.Quit
End If
end sub
sub ListUpdatesNeeded 'print list of updates needed
'list all updates that are not language packs - and their download status
'update properties: http://msdn.microsoft.com/en-us/library/aa386099(VS.85).aspx
'TODO: skip updates that require EULA checks. or have a commandline that accepts the EULA
Wscript.Echo
Dim RequestsInput, WantsReboot, HighImpact, NeedsNetwork, LanguagePack, DontInstall
Dim Eula, I, update, downloadstatus, downloadcount
If searchResult.Updates.Count > 0 Then
Wscript.Echo "List of outstanding updates (not including driver updates):"
Wscript.Echo " |-------- D: Needs download (script will download)"
Wscript.Echo " ||------- R: Reboot required"
Wscript.Echo " |||------ I: Requires user input"
Wscript.Echo " ||||----- H: High Impact (must install separately)"
Wscript.Echo " |||||---- N: Needs network to properly install"
Wscript.Echo " ||||||--- E: Requires EULA acceptance before install"
Wscript.Echo " |||||||-- L: Language Pack"
End If
For I = 0 To searchResult.Updates.Count-1
DontInstall = 0
RequestsInput = "-"
WantsReboot = "-"
HighImpact = "-"
NeedsNetwork = "-"
Eula = "-"
LanguagePack = "-"
Set update = searchResult.Updates.Item(I)
If InStr(CStr(update.Title),"Language Pack") <> 0 Then 'don't download/install
LanguagePack = "L"
DontInstall = DontInstall + 1
End If
If update.EulaAccepted = False Then 'only install if /accepteula arg was given
Eula = "E"
If colArgs.Exists("accepteula") = False Then
DontInstall = DontInstall + 1
Else
updatesToDownload.Add(update)
updatesToInstall.Add(update)
update.AcceptEula()
End If
End If
If update.InstallationBehavior.CanRequestUserInput = True Then 'don't download/install
RequestsInput = "I"
DontInstall = DontInstall + 1
End If
If update.InstallationBehavior.Impact = 3 Then 'don't download/install
HighImpact = "H"
DontInstall = DontInstall + 1
End If
If update.InstallationBehavior.RequiresNetworkConnectivity Then 'don't download/install
NeedsNetwork = "N"
DontInstall = DontInstall + 1
End If
If update.InstallationBehavior.RebootBehavior <> 0 Then WantsReboot = "R"
If update.IsDownloaded Then
downloadstatus = "-"
If DontInstall = 0 Then updatesToInstall.Add(update)
Else
downloadstatus = "D"
If DontInstall = 0 Then
updatesToDownload.Add(update)
updatesToInstall.Add(update)
End If
End If
WScript.Echo " "& downloadstatus & WantsReboot & RequestsInput & HighImpact & NeedsNetwork & LanguagePack & Eula &_
" "& update.Title
Next
Wscript.Echo
Wscript.Echo searchResult.Updates.Count & " update(s) found. " & updatesToInstall.Count & " eligible for install by this script."
Wscript.Echo "(This script will NOT download/install updates with I, H, N, or L properties.)"
Wscript.Echo "(Updates with the E property will be installed if /accepteula arg was given.)"
If updatesToInstall.Count = 0 Then Wscript.Quit
If colArgs.Exists("checkonly") Then
Wscript.Echo
Wscript.echo "You can run this script again, without the /checkonly param,"
Wscript.Echo "to apply updates."
Wscript.Quit
End If
end sub
sub CheckIfAdmin 'see if current user has admin privs; if Vista/2008 see if they hold elevated token
'If the script isn't running with admin privs, exit now. Else fall through to DownloadUpdates
Dim strOSFamily
strOSFamily = OSFamily
Select Case strOSFamily
Case "2000"
If MemberOfAdministrators = 0 Then NoPrivExit
Case "XP"
If MemberOfAdministrators = 0 Then NoPrivExit
Case "2003"
If MemberOfAdministrators = 0 Then NoPrivExit
Case "Vista"
If IsElevated = 0 Then NoPrivExit
Case "2008"
If IsElevated = 0 Then NoPrivExit
Case Else
Wscript.Echo "Script halted: the current OS is not recognized."
Wscript.Echo "Update the OSFamily function and CheckIfAdmin sub."
Wscript.Quit
End Select
End Sub
sub DownloadUpdates 'download any needed updates
If updatesToDownload.Count > 0 Then
Wscript.Echo
Wscript.Echo "Downloading the needed updates. This takes time!"
Dim downloader, dlItem, currdownload, dlresult
failcount = 0
Set downloader = updateSession.CreateUpdateDownloader()
Set currdownload = CreateObject("Microsoft.Update.UpdateColl")
For Each dlItem in updatesToDownload
Wscript.stdout.Write(" " & dlItem.Title &" .. ")
currdownload.Add(dlItem)
downloader.Updates = currdownload
downloader.Download()
If dlItem.IsDownloaded Then
dlresult = "downloaded"
Else
dlresult = "DOWNLOAD FAILED"
failcount = failcount + 1
End If
Wscript.stdout.WriteLine(CStr(dlresult))
currdownload.Clear()
Next
End If
end sub
sub ApplyUpdates 'apply the updates
If updatesToInstall.Count > 0 Then
Wscript.Echo
Wscript.Echo "Installing the updates. Again, it takes time."
Dim installer, currinstall, instItem, installResult ', rebootcount
rebootcount = 0
Set installer = updateSession.CreateUpdateInstaller()
Set currinstall = CreateObject("Microsoft.Update.UpdateColl")
For Each instItem in updatesToInstall
currinstall.Add(instItem)
installer.Updates = currinstall
Wscript.stdout.Write(" " & instItem.Title & " .. ")
on error resume next
Set installResult = installer.Install()
If Err.Number <> 0 Then
Wscript.stdout.WriteLine
Call WUAerror(Err.Number, Err.Description)
End if
Select Case installResult.ResultCode 'http://msdn.microsoft.com/en-us/library/aa387095(VS.85).aspx
Case 0
Wscript.stdout.Write("ERROR - not started")
Case 1
Wscript.stdout.Write("ERROR - in progress")
Case 2
Wscript.stdout.Write("Success")
If installResult.RebootRequired = true Then
Wscript.stdout.WriteLine(" - REBOOT REQUIRED")
rebootcount = rebootcount + 1
Else
Wscript.stdout.WriteLine
End If
Case 3
Wscript.stdout.Write("ERROR - succeeded, but with errors")
If installResult.RebootRequired = true Then
Wscript.stdout.WriteLine(" - REBOOT REQUIRED")
rebootcount = rebootcount + 1
Else
Wscript.stdout.WriteLine
End If
Case 4
Wscript.stdout.Write("ERROR - failed")
Case 5
Wscript.stdout.Write("ERROR - aborted")
Case Else
Wscript.stdout.Write("ERROR - unknown error")
End Select
If installResult.ResultCode <> 2 Then failcount = failcount + 1
On Error GoTo 0
Next
End If
end sub
Function WUAerror(ErrNumber, ErrDesc) 'handle various WUA errors
'from here: http://msdn.microsoft.com/en-us/library/aa387293(VS.85).aspx, retreived 2008-10-31
On Error Goto 0
Wscript.stdout.Write "WUA ERROR " & CStr(Hex(ErrNumber)) & " - "
Select Case "0x" & CStr(Hex(ErrNumber))
Case "0x8024402C" Wscript.stdout.WriteLine "The proxy server or target server name cannot be resolved."
Case "0x80244016" Wscript.stdout.WriteLine "The server could not process the request due to invalid syntax."
Case "0x80244017" Wscript.stdout.WriteLine "The requested resource requires user authentication."
Case "0x80244018" Wscript.stdout.WriteLine "Server understood the request, but declines to fulfill it."
Case "0x80244019" Wscript.stdout.WriteLine "The server cannot find the requested URI (Uniform Resource Identifier)."
Case "0x8024401A" Wscript.stdout.WriteLine "The HTTP method is not allowed."
Case "0x8024401B" Wscript.stdout.WriteLine "Proxy authentication is required."
Case "0x8024401C" Wscript.stdout.WriteLine "The server timed out waiting for the request."
Case "0x8024401D" Wscript.stdout.WriteLine "The request was not completed due to a conflict with the current state of the resource."
Case "0x8024401E" Wscript.stdout.WriteLine "Requested resource is no longer available at the server."
Case "0x8024401F" Wscript.stdout.WriteLine "An error internal to the server prevented fulfilling the request."
Case "0x80244020" Wscript.stdout.WriteLine "Server does not support the functionality required to fulfill the request."
Case "0x80244021" Wscript.stdout.WriteLine "The server, while acting as a gateway or proxy, received an invalid response from the upstream server it accessed in attempting to fulfill the request."
Case "0x80244022" Wscript.stdout.WriteLine "The service is temporarily overloaded."
Case "0x80244023" Wscript.stdout.WriteLine "The request was timed out waiting for a gateway."
Case "0x80244024" Wscript.stdout.WriteLine "The server does not support the HTTP protocol version used for the request."
Case "0x80240016" Wscript.stdout.WriteLine "Cannot access user token. http://support.microsoft.com/kb/957307"
Case Else Wscript.stdout.WriteLine "Unknown error 0x" & CStr(Hex(ErrNumber)) & " (sorry)."
End Select
end function
Function MemberOfAdministrators 'see if current user is in Administrators group
Dim WshNetwork, CurrUser, oGroup, oUser
Set WshNetwork = WScript.CreateObject("WScript.Network")
currUser = WshNetwork.UserName
MemberOfAdministrators = 0
set oGroup = GetObject("WinNT://./Administrators,group")
For Each oUser in oGroup.Members
If InStr(1,oUser.Name,currUser,vbTextCompare) Then MemberOfAdministrators = 1
Next
end Function
Function OSFamily 'discover current OS family -200. XP, 2003, Vista, 2008
Dim strComputer, oWMIService, colOSInfo, oOSProperty, strCaption, strOSFamily
strComputer = "."
Set oWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colOSInfo = oWMIService.ExecQuery("Select * from Win32_OperatingSystem")
'I dislike looping through just to get one property. But dunno another way!
For Each oOSProperty in colOSInfo
strCaption = oOSProperty.Caption
Next
If InStr(1,strCaption, "Vista", vbTextCompare) Then
OSFamily = "Vista"
ElseIf InStr(1,strCaption, "2008", vbTextCompare) Then
OSFamily = "2008"
ElseIf InStr(1,strCaption, "XP", vbTextCompare) Then
OSFamily = "XP"
ElseIf InStr(1,strCaption, "2003", vbTextCompare) Then
OSFamily = "2003"
ElseIf InStr(1,strCaption, "2000", vbTextCompare) Then
OSFamily = "2000"
Else
OSFamily = "Unknown OS"
End If
end Function
Function IsElevated 'test whether user has elevated token
'parses whoami.exe output. I verified whoami.exe is in Vista Home Basic and above.
IsElevated = 0
Dim oShell, oExecWhoami, oWhoamiOutput, strWhoamiOutput
Set oShell = CreateObject("WScript.Shell")
Set oExecWhoami = oShell.Exec("whoami /groups")
Set oWhoamiOutput = oExecWhoami.StdOut
strWhoamiOutput = oWhoamiOutput.ReadAll
If InStr(1, strWhoamiOutput, "S-1-16-12288", vbTextCompare) Then IsElevated = 1
end Function
Function WuaVersion 'get current WUA version
Dim oAgentInfo, ProductVersion
On Error Resume Next
Err.Clear
Set oAgentInfo = CreateObject("Microsoft.Update.AgentInfo")
If ErrNum = 0 Then
WuaVersion = oAgentInfo.GetInfo("ProductVersionString")
Else
Wscript.Echo "Error getting WUA version."
WuaVersion = 0
End If
On Error Goto 0
End Function
Function OScpuEdition 'Find out if x32 or x64 Windows
'doesn't detect Itanium because no Itanium system to test with
Dim strComputer, oWMIService, colCPUInfo, oCPUProperty
strComputer = "."
Set oWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colCPUInfo = oWMIService.ExecQuery("Select AddressWidth from Win32_Processor")
For Each oCPUProperty in colCPUInfo
OScpuEdition = oCPUProperty.AddressWidth
Next
End Function
Function DownloadFile(DownloadUrl) 'generic file downloader, saves to temp
'Get name of file from url (whatever follows the final forwardslash "/")
Dim arURL, FileName, FileSaveLocation
arURL = Split(DownloadUrl,"/",-1,1)
If arURL(UBound(arURL)) = "" Then 'if there is a trailing forwardslash
FileName = arURL(UBound(arURL) -1)
Else
filename = arURL(UBound(arURL))
End If
'Get temp folder location
Dim oFS, TempDir
Set oFS = CreateObject("Scripting.FileSystemObject")
Set TempDir = oFS.getSpecialFolder(2)
FileSaveLocation = TempDir & "\" & FileName
'Fetch the file
Dim oXMLHTTP, oADOStream
Set oXMLHTTP = CreateObject("MSXML2.XMLHTTP")
oXMLHTTP.open "GET", DownloadUrl, false
oXMLHTTP.send()
If oXMLHTTP.Status = 200 Then
Set oADOStream = CreateObject("ADODB.Stream")
oADOStream.Open
oADOStream.Type = 1 'adTypeBinary
oADOStream.Write oXMLHTTP.ResponseBody
oADOStream.Position = 0 'Set the stream position to the start
If oFS.Fileexists(FileSaveLocation) Then oFS.DeleteFile FileSaveLocation
Set oFS = Nothing
oADOStream.SaveToFile FileSaveLocation
oADOStream.Close
Set oADOStream = Nothing
End if
Set oXMLHTTP = Nothing
End Function
sub NoPrivExit
Wscript.Echo "Administrative privileges are required to apply updates."
Wscript.Echo "Since the script was not running with Admin privs, halting before download."
Wscript.Echo "Please try again with proper privs."
Wscript.Quit
End Sub
Sub CleanupExit 'inform user of status and exit
Wscript.Echo
Wscript.Echo "Script complete. " & updatesToInstall.Count & " updates were needed, " & failcount & " updates failed to download and/or install."
If rebootcount > 0 Then
Wscript.Echo "A ***REBOOT*** is required for some of the updates to take effect."
If UCase(colargs.Item("reboot")) = "YES" Then
Wscript.Echo
Wscript.Echo "REBOOTING in 30 seconds! (""CTRL-C"" to abort)"
Wscript.Echo Chr(7) 'beep
Wscript.Sleep(30000)
Dim OpSysSet, OpSys, wmiquery
wmiquery = "select * from Win32_OperatingSystem where Primary=true"
Set OpSysSet = GetObject("winmgmts:{(Shutdown)}//./root/cimv2").ExecQuery(wmiquery)
For Each OpSys in OpSysSet
OpSys.Reboot()
Next
Else
Wscript.Echo "/reboot:no was specified in script arguments, so please reboot when you can."
End If
Else
Wscript.Echo "No reboots were called for by the installed updates."
End If
Wscript.Quit
end sub
sub HelpExit 'provide help text and exit
Wscript.Echo
Wscript.Echo "Usage Examples:"
Wscript.Echo
Wscript.Echo "cscript " & Wscript.ScriptName & " /reboot:yes /accepteula"
Wscript.Echo "cscript " & Wscript.ScriptName & " /checkonly"
Wscript.Echo
Wscript.Echo "Arguments:"
Wscript.Echo
Wscript.Echo "/reboot: can be ""yes"" or ""no"". "
Wscript.Echo " (will only reboot if one or more updates actually call for reboot)"
Wscript.Echo "/checkonly - if this arg is specified, script checks for updates, "
Wscript.Echo " but does not download or apply them."
Wscript.Echo "/accepteula - some updates require a EULA acceptance; this param will"
Wscript.Echo " cause the EULA to be accepted automatically."
Wscript.Echo "/updatewua - updates Windows Update Agent if needed."
Wscript.Echo
Wscript.Echo "NOTES"
Wscript.Echo
Wscript.Echo "You must specify at least one argument, or you will get this help screen."
Wscript.Echo "You may specify multiple arguments, but /checkonly should be used "
Wscript.Echo "without any others."
Wscript.Echo
Wscript.Echo "The download and install operations will require admin privileges."
Wscript.Echo "Script will list updates then exit if admin privs are not held."
Wscript.Echo
Wscript.Echo "Script will list all non-driver updates available from Windows Update that have"
Wscript.Echo "not been applied to the system. However it will NOT apply Language Packs,"
Wscript.Echo "High Impact updates (which must be installed by themselves), or"
Wscript.Echo "updates which require user input or network connectivity."
Wscript.Echo
Wscript.Echo "Currently the script does not provide an exit status code though it"
Wscript.Echo "does attempt to be verbose (via stdout) about why it exits."
Wscript.Quit
end sub
quux's mexican jumping wiki 
Uploading ....